.cpu cortex-m0plus
.thumb
.align 2
.thumb_func

.section .vector
.global vector
vector:
	.word	0x20041000
	.word	reset + 1

.section .text
.global reset
reset:
	ldr	r7, =0x4000f000		@ RESETS_RESET  + 0x3000
	mov	r0, #(1<<5)		@ IO_BANK0
	str	r0, [r7, #0x00]
	ldr	r7, =0x400140cc		@ IO_BANK0_GPIO25_CTRL
	mov	r0, #5			@ SIO
	str	r0, [r7, #0x00]
	ldr	r7, =0xd0000000		@ SIO_GPIO_BASE
	ldr	r0, =(1<<25)		@ GPIO25
	str	r0, [r7, #0x20]		@ SIO_GPIO_BASE_OE

1:	str	r0, [r7, #0x1C]		@ SIO_GPIO_BASE_XOR
	b	1b
		

这个程序包含了一个异或输出的死循环。

根据指令集文档：

1. str r0, [r7, #0x1C] - 写入GPIO 25（SIO）消耗1个CPU时钟周期。
2. b 1b - 跳转并修改了PC消耗2个CPU时钟周期。

算下来，GPIO 25没3个CPU时钟周期翻转一次，波形周期为6个CPU时钟周期（3高3低）。

MEMORY {
	SRAM(rwx) : ORIGIN = 0x20000000, LENGTH = 264k
	SRAM_4(rwx) : ORIGIN = 0x20040000, LENGTH = 4k
	SRAM_5(rwx) : ORIGIN = 0x20041000, LENGTH = 4k
	SRAM_0(rwx) : ORIGIN = 0x21000000, LENGTH = 64k
	SRAM_1(rwx) : ORIGIN = 0x21010000, LENGTH = 64k
	SRAM_2(rwx) : ORIGIN = 0x21020000, LENGTH = 64k
	SRAM_3(rwx) : ORIGIN = 0x21030000, LENGTH = 64k
}

ENTRY(reset)

SECTIONS {
	.text : {
		*(reset)
	} > SRAM
}
		

只需要将reset程序装入SRAM，不需要vector。

进入点为reset程序。

MEMORY {
	FLASH(rwx) : ORIGIN = 0x10000000, LENGTH = 2048k
}

SECTIONS {
	.text : {
		*(.boot2)
		*(.vector)
		*(reset)
	} > FLASH
}
		

根据片上引导程序的要求，先将之前文章中生成的二级引导程序.boot放在闪存的开头。再根据二级引导程序的要求，将向量表vector放在紧接着二级引导程序的地方。最后，装入reset程序。

闪存编程不需要指定进入点。

arm-none-eabi-as --warn --fatal-warnings -g main.s -o main.o
arm-none-eabi-objdump --disassembler-options=force-thumb -Dxs main.o > main.list

# SRAM
arm-none-eabi-ld -nostdlib -nostartfiles -T sram.ld main.o -o sram.elf
arm-none-eabi-objdump --disassembler-options=force-thumb -dxs sram.elf > sram.list
pico-elf2uf2 sram.elf sram.uf2

# Flash
arm-none-eabi-ld -nostdlib -nostartfiles -T flash.ld main.o boot2.o -o flash.elf
arm-none-eabi-objdump --disassembler-options=force-thumb -dxs flash.elf > flash.list
pico-elf2uf2 flash.elf flash.uf2
		

编译这个项目，将生成两个uf2文件：

• sram.uf2 - 下载到并从SRAM执行。
• flash.uf2 - 烧录入并从闪存执行，允许在掉电后保留程序。

现在，我们可以使用示波器来检测输出信号。我们将在这里。也就是LED电阻的高侧测量信号。见上图所示测试点。

如示波器展示，该信号频率为966kHz。因为波形周期为6个CPU时钟周期，CPU的频率为5.8MHz。

说好的133MHz呢？

PR2040提供了一些列的时钟源。如图左侧所展示。注意有的时钟源由另外的时钟源驱动。

时钟生成器选择一个时钟源，使用分频器降低时钟频率（省电或满足使用者的最高速度）。如图中间所展示。

时钟信号输出到使用者，包括系统（CPU核心）、外置设备、时钟输出。

时钟选项

一个时钟输出可以被用作另一个时钟的输入。细节参考时钟生成器各自的控制寄存器。下面是我整理的结果：

CLK_GPIO_0 / CLK_GPIO_1

0. CLKSRC_PLL_SYS
1. CLKSRC_GPIN0
2. CLKSRC_GPIN1
3. CLKSRC_PLL_USB
4. ROSC_CLKSRC
5. XOSC_CLKSRC
6. CLK_SYS
7. CLK_USB
8. CLK_ADC
9. CLK_RTC
10. CLK_REF

CLK_GPIO_2 / CLK_GPIO_3

0. CLKSRC_PLL_SYS
1. CLKSRC_GPIN0
2. CLKSRC_GPIN1
3. CLKSRC_PLL_USB
4. ROSC_CLKSRC_PH（移相）
5. XOSC_CLKSRC
6. CLK_SYS
7. CLK_USB
8. CLK_ADC
9. CLK_RTC
10. CLK_REF

CLK_REF

0. ROSC_CLKSRC_PH
1. CLKSRC_CLK_REF_AUX
   0. CLKSRC_PLL_USB
   1. CLKSRC_GPIN0
   2. CLKSRC_GPIN1
2. XOSC_CLKSRC

CLK_SYS

0. CLK_REF
1. CLKSRC_CLK_SYS_AUX
   0. CLKSRC_PLL_SYS
   1. CLKSRC_PLL_USB
   2. ROSC_CLKSRC
   3. XOSC_CLKSRC
   4. CLKSRC_GPIN0
   5. CLKSRC_GPIN1

CLK_PERI

0. CLK_SYS
1. CLKSRC_PLL_SYS
2. CLKSRC_PLL_USB
3. ROSC_CLKSRC_PH
4. XOSC_CLKSRC
5. CLKSRC_GPIN0
6. CLKSRC_GPIN1

CLK_USB / CLK_ADC / CLK_RTC

0. CLKSRC_PLL_USB
1. CLKSRC_PLL_SYS
2. ROSC_CLKSRC_PH
3. XOSC_CLKSRC
4. CLKSRC_GPIN0
5. CLKSRC_GPIN1

.cpu cortex-m0plus
.thumb
.align 2
.thumb_func

.section .vector
.global vector
vector:
	.word	0x20041000
	.word	reset + 1

.section .text
.global reset
reset:

@ Switch to XOSC
	ldr	r7, =0x40008000
	mov	r0, #((3<<5) | (0<<0))
	str	r0, [r7, #0x3C]
	nop
	nop
	nop
	nop
	mov	r0, #((3<<5) | (1<<0))
	str	r0, [r7, #0x3C]

@ GPIO
	ldr	r7, =0x4000f000		@ RESETS_RESET  + 0x3000
	mov	r0, #(1<<5)		@ IO_BANK0
	str	r0, [r7, #0x00]
	ldr	r7, =0x400140cc		@ IO_BANK0_GPIO25_CTRL
	mov	r0, #5			@ SIO
	str	r0, [r7, #0x00]
	ldr	r7, =0xd0000000		@ SIO_GPIO_BASE
	ldr	r0, =(1<<25)		@ GPIO25
	str	r0, [r7, #0x20]		@ SIO_GPIO_BASE_OE

1:	str	r0, [r7, #0x1C]		@ SIO_GPIO_BASE_XOR
	b	1b
			

首先，同时修改系统时钟控制器的辅助选择器和连续选择器：

• 连续选择器切换到参考时钟源。这个切换操作可以随时执行。如果连续选择器当前已经选择了参考时钟源，该切换操作将没有效果。如果连续选择器当前选择了辅助选择器，该切换操作将会隔离即将毛刺的辅助选择器。
• 辅助选择器切换到新的时钟源。本例子中为晶体振荡器。

等待4个（ROSC）周期。因为ROSC的频率为5.8MHz但XOSC为12MHz，4个ROSC周期肯定比2个ROSC周期加2个XOSC周期要长。另外，写r0和写控制寄存器也会提供额外的时间。

现在，辅助选择器应该稳定了。我们可以将连续选择器切换回辅助选择器上。

使用默认分频（1）。

The glitchless multiplexer does not switch instantaneously (to avoid glitches)（连续选择器为了防止毛刺并不会立刻切换），要等待几个周期后才会真的切换到新的时钟上。可以通过CLOCKS_CLK_SYS_SELECTED寄存器来确认时钟源已切换。在这个例子中我们并不担心这个问题。

.cpu cortex-m0plus
.thumb
.align 2
.thumb_func

.section .vector
.global vector
vector:
	.word	0x20041000
	.word	reset + 1

.section .text
.global reset
reset:

@ Start XOSC
	ldr	r7, =0x40024000
	ldr	r0, =0x00FABAA0
	str	r0, [r7, #0x00]
1:	ldr	r0, [r7, #0x04]
	lsr	r0, #32
	bcc	1b

@ Switch to XOSC
	ldr	r7, =0x40008000
	mov	r0, #((3<<5) | (0<<0))
	str	r0, [r7, #0x3C]
	nop
	nop
	mov	r0, #((3<<5) | (1<<0))
	str	r0, [r7, #0x3C]

@ GPIO
	ldr	r7, =0x4000f000		@ RESETS_RESET  + 0x3000
	mov	r0, #(1<<5)		@ IO_BANK0
	str	r0, [r7, #0x00]
	ldr	r7, =0x400140cc		@ IO_BANK0_GPIO25_CTRL
	mov	r0, #5			@ SIO
	str	r0, [r7, #0x00]
	ldr	r7, =0xd0000000		@ SIO_GPIO_BASE
	ldr	r0, =(1<<25)		@ GPIO25
	str	r0, [r7, #0x20]		@ SIO_GPIO_BASE_OE

1:	str	r0, [r7, #0x1C]		@ SIO_GPIO_BASE_XOR
	b	1b
			

要启动XOSC，设置XOSC_CTRL寄存器中ENABLE密码与FREQ_RANGE。ENABLE必须是0xFAB，FREQ_RANGE必须是0xAA0。

接下来，轮询XOSC_STATUS中STABLE值直到XOSC稳定。

现在就可以使用XOSC了。

.cpu cortex-m0plus
.thumb
.align 2
.thumb_func

.section .vector
.global vector
vector:
	.word	0x20041000
	.word	reset + 1

.section .text
.global reset
reset:

@ Start XOSC
	ldr	r7, =0x40024000
	ldr	r0, =0x00FABAA0
	str	r0, [r7, #0x00]
1:	ldr	r0, [r7, #0x04]
	lsr	r0, #32
	bcc	1b
			

系统PLL和USB PLL都需要使用XOSC为参考时钟。因此，我们需要启用先XOSC。细节参考上一个例子。

@ Start PLL
	ldr	r7, =0x4000f000
	ldr	r0, =(1<<12)
	str	r0, [r7, #0x00]
			

上电后，系统PLL出于重置状态。我们需要写1来解除该状态才能使用PLL。为了保持其它设备的重置状态，我们可以添加0x3000的地址偏移来原子性地写1清零比特。

	ldr	r7, =0x40028000
	ldr	r6, =0x40028000 + 0x3000
	mov	r0, #(1<<0)
	str	r0, [r7, #0x00]
	mov	r0, #66
	str	r0, [r7, #0x08]
			

RP2040有两套PLL，一个是最高133MHz的系统的，另一个时48MHz的USB的。系统PLL的控制寄存器基地址为0x40028000，USB PLL的控制寄存器基地址为0x4002C000。

使用r7作为系统PLL的控制寄存器的指针，使用r6系统PLL的控制寄存器的写1清零指针。

首先，设置参考时钟分频器为1。因为板载晶体为12MHz，这将会把12MHz / 1 = 12MHz的参考信号输入PLL。该设置有助于在芯片驱动时钟太高时降频参考信号。

接下来，设置反馈分频器为66。这会使VCO的频率达到12MHz * 66 = 792MHz。

	mov	r0, #((1<<5) | (1<<0))
	str	r0, [r6, #0x04]
1:	ldr	r0, [r7, #0x00]
	lsr	r0, r0, #32
	bcc	1b
			

默认情况下，PLL的各个部分都是断电的。给VCO与PLL上电以启动PLL，但是不要启动后段分频器。

需要等待一阵频率才会稳定，PLL才能锁住。我们可以通过轮询PLL_SYS_CS寄存器中LOCK比特来确认PLL准备好了。

	ldr	r0, =((6<<16) | (1<<12))
	str	r0, [r7, #0x0C]
	mov	r0, #(1<<3)
	str	r0, [r6, #0x04]
			

设置两级后段分频器。我们使用6为第一段分频器，1为第二段分频器。这将会将频率降低到792MHz / 6 / 1 = 132MHz。

给后段分频器上电。

@ Switch to PLL
	ldr	r7, =0x40008000
	mov	r0, #((0<<5) | (0<<0))
	str	r0, [r7, #0x3C]
	nop
	nop
	mov	r0, #((0<<5) | (1<<0))
	str	r0, [r7, #0x3C]
			

切换辅助选择器与连续选择器为系统PLL。细节参考上一个例子。